# Circuit RLC Serie

Josep Pujadas i Jubany (jpujades a gmail punt com)
04-abril-2011

Els textos no porten accents perque es vegin be tant en sistemes operatius nous (UTF-8)
com en antics (ISO-8859-15). NO FEU SERVIR DONCS ACCENTS A LES EXPLICACIONS.

Fes:
- Cell - Evaluate All Cells
- Celda - Evaluar todas las celdas
per a veure els resultats.

Dades, amb unitats del SI (Sistema Internacional).
E [V], [Volt]
f [Hz], [Hertz]
R [Ohm]
L [H], [Henry]
C [F], [Faraday]

E:48$
f:50$
R:50$
L:10*10^(-3)$
C:150*10^(-6)$

Calcul d'omega, [rad]

%omega:2*%pi*f$
float(%omega);

Calcul de XL (reactancia inductiva) i XC (reactancia capacitiva), [Ohm]
Calcul de X (reactancia), [Ohm]
RECORDA:
- X positiva -> Circuit inductiu (predomina la bobina).
- X negativa -> Circuit capacitiu (predomina el condensador).
- X cero -----> Circuit ressonant, si hi ha bobina i condensador.

XL:%omega*L$
float(XL);
if C # 0 then XC:1/(%omega*C) else XC:0$
float(XC);
X:XL-XC$
float(X);

Calcul de Z (impedancia total), [Ohm]
L'angle s'obte en radians (per a les sinusoidals).
Per veure'l millor es dona tambe en graus sexagesimals.
RECORDA:
- Angle positiu -> Circuit inductiu (predomina la bobina).
- Angle negatiu -> Circuit capacitiu (predomina el condensador).
- Angle cero ----> Circuit ressonant, si hi ha bobina i condensador.

Z:sqrt(R^2+X^2)$
float(Z);
if R = 0 then (if X > 0 then PHI:%pi/2 else (if X < 0 then PHI:-%pi/2 else PHI:0)) else PHI:atan(X/R)$
float(PHI);
float(PHI*180/%pi);

Calcul de Emax (f.e.m. maxima d'alimentacio), [V]

Emax:E*sqrt(2)$
float(Emax);

Sinusoidal de la f.e.m. d'alimentacio, [V]

e(t):=Emax*sin(%omega*t);

Sinusoidal de la intensitat del circuit, [A]

Imax:Emax/Z$
float(Imax);
i(t):=Imax*sin((%omega*t)-PHI);

Sinusoidals de les caigudes de tensio a R, L i C, [V]

Vrmax:Imax*R$
float(Vrmax);
vr(t):=Vrmax*sin((%omega*t)-PHI);
Vlmax:Imax*XL$
float(Vlmax);
vl(t):=Vlmax*sin((%omega*t)-PHI+(%pi/2));
Vcmax:Imax*XC$
float(Vcmax);
vc(t):=Vcmax*sin((%omega*t)-PHI-(%pi/2));

Representacio grafica de les sinusoidals.
La intensitat es dibuixa sempre amb una amplitud la meitat de la de la tensio.

Ymax:max(Emax,Vrmax,Vlmax,Vcmax)$
plot2d([e(t),Z/2*i(t),vr(t),vl(t),vc(t)], [t,-0.25/f,1.25/f], [y,-Ymax-5,Ymax+5],
 [style, [lines,3],[lines,3],[lines,1],[lines,1],[lines,1]],
 [legend, "e(t)","(Z/2)*i(t)", "vr(t)", "vl(t)", "vc(t)"], [ylabel,"V,A"],
 [plot_format, gnuplot], [gnuplot_preamble, "set grid;"])$

Frequencia de ressonancia, [Hz]

if L = 0 or C = 0 then fr:0 else fr:1/(2*%pi*(sqrt(L*C)))$
float(fr);

Comprovacio grafica de les tensions.
Les sinusoidals e(t) i v(t) son la mateixa funcio.
Nomes es veu una funcio perque l'altra queda amagada a sota.

v(t):=vr(t)+vl(t)+vc(t)$
plot2d([e(t),v(t)], [t,-0.25/f,1.25/f], [y,-Emax-5,Emax+5],
 [legend, "e(t)","v(t)"], [ylabel,"V"], 
 [plot_format, gnuplot], [gnuplot_preamble, "set grid;"])$